c Arabic keyboard
c To be used with the font ArabicNaskhSSK

Name "Arabic"
Bitmaps arabic1 arabic0
Hotkey "^%A"
Version 3.2

begin > use(main)

store (NoConnectInd) 'AegikËÜÑ'
store (NoConnectFin) 'BfhjlÌÝÒ'

store (ConnectInd) 'LPTX`dptx~¢¦ª®²¶º¾ÂÆÊÐ'
store (ConnectInit) 'IMQUYamquy£§«¯³·»¿ÃÇÍ'
store (ConnectMed) 'JNRVZbnrvzñ¤¨¬°´¸¼ÀÄÈÎ' 
store (ConnectFin) 'KOSW\cosw|¡¥©­±µ¹½ÁÅÉÏ'

store (NoConnectKey) 'edvrzwLH'
store (ConnectKey) 'btpjxXscSDTZgGfqklmnhy'

store(VowelKey) 'aAiIuU'
store(Vowel) 'äòêøåó'
store(SignKey) 'oO`~'
store(Sign) 'é÷æô'

store(Consonant) 'ABLIJKPMNOTQRSXUVW`YZ\dabcefghijklpmnotqrsxuvw~yz|¢¡ñ¦¥£¤ª©§¨®­«¬²±¯°¶µ³´º¹·¸¾½»¼ÂÁ¿ÀÆÅÃÄÊÉÇÈËÌÐÏÍÎ'
group(Main) using keys
any(NoConnectKey) > index(NoConnectInd,1)
any(ConnectKey) > index(ConnectInd,1)

any(NoConnectInd) + any(ConnectKey) > index(NoConnectFin,1) + index (ConnectInit,2)
any(ConnectInd) + any (ConnectKey) > index(ConnectFin,1) + index(ConnectInit,2)

any(ConnectInit) + any(ConnectKey) > index(ConnectMed,1) + index(ConnectInit,2)

any(NoConnectInd) + '>' > index(NoConnectInd,1) + beep
any(ConnectInd) + '>' > index(ConnectInit,1)
any(NoConnectFin) + '>' > index(NoConnectFin,1) + beep
any(ConnectFin) + '>' > index(ConnectInit,1) 
any(ConnectInit) + '>' > index(ConnectInit,1) + beep
any(ConnectMed) + '>' > index(ConnectInit,1) 

any(NoConnectInd) + '<' > index(NoConnectFin,1)
any(ConnectInd) + '<' > index(ConnectFin,1)
any(NoConnectFin) + '<' > index(NoConnectFin,1) + beep
any(ConnectFin) + '<' > index(ConnectFin,1) + beep
any(ConnectInit) + '<' > index(ConnectFin,1)
any(ConnectMed) + '<' > index(ConnectFin,1)

any(NoConnectInd) + '=' > index(NoConnectInd,1) + beep
any(ConnectInd) + '=' > index(ConnectInd,1) + beep
any(NoConnectFin) + '=' > index(NoConnectInd,1)
any(ConnectFin) + '=' > index(ConnectInd,1)
any(ConnectInit) + '=' > index(ConnectInd,1)
any(ConnectMed) + '=' > index(ConnectInd,1)

any(NoConnectInd) + '-' > index(NoConnectInd,1) + beep
any(ConnectInd) + '-' > index(ConnectMed,1)
any(NoConnectFin) + '-' > index(NoConnectFin,1) + beep
any(ConnectFin) + '-' > index(ConnectMed,1)
any(ConnectInit) + '-' > index(ConnectMed,1)
any(ConnectMed) + '-' > index(ConnectMed,1) + beep

c EXTRA LINES
any(ConnectInd) + '@' > index(ConnectFin,1) + '@'
any(ConnectInit) + '@' > index(ConnectMed,1) + '@'
any(NoConnectInd) + '@' > index(NoConnectFin,1) + '@'
'@' + any(ConnectKey) > '@' + index(ConnectInit,2)
'@' + any(NoConnectKey) > '@' + index(NoConnectInd,2)

c VOWELS
any(Consonant) + any(VowelKey) > index(Vowel,2) + index(Consonant,1)

any(NoConnectInd) + any(Vowel) + any(ConnectKey) > index(NoConnectFin,1) + index(Vowel,2) +  index (ConnectInit,3)
any(ConnectInd) + any(Vowel) + any (ConnectKey) > index(ConnectFin,1) + index(Vowel,2) + index(ConnectInit,3)
any(ConnectInit) + any(Vowel) + any(ConnectKey) > index(ConnectMed,1) + index(Vowel,2) + index(ConnectInit,3)

any(Vowel) + any(Consonant) + any(VowelKey) > index(Vowel,3) +  index(Consonant,2) 

c OTHER SIGNS
any(Consonant) + any(SignKey) > index(Sign,2) + index(Consonant,1)

any(NoConnectInd) + any(Sign) + any(ConnectKey) > index(NoConnectFin,1) + index(Sign,2) +  index (ConnectInit,3)
any(ConnectInd) + any(Sign) + any (ConnectKey) > index(ConnectFin,1) + index(Sign,2) + index(ConnectInit,3)
any(ConnectInit) + any(Sign) + any(ConnectKey) > index(ConnectMed,1) + index(Sign,2) + index(ConnectInit,3)

'é' + any(Consonant) + 'O' > '÷' + index(Consonant,2)
'æ' + any(Consonant) + '~' > 'ô' + index(Consonant,2)
'÷' + any(Consonant) + 'o' > 'é' + index(Consonant,2)
'ô' + any(Consonant) + '`' > 'æ' + index(Consonant,2)